History: Setting Up An Application - Mac OSX

View published page Collapse Into Edit Sessions

Preview of version: 27

Introduction

When it comes to creating and compiling your own applications or the Ogre Tutorial Framework on OSX, you have the choice of using CMake or XCode templates to generate your initial XCode project. If you are planning on developing using XCode, the XCode templates are a quick way to get up and running. A full description of the steps for using the XCode templates can be found here: http://www.ogre3d.org/tikiwiki/tiki-index.php?page_ref_id=2019

If you would like to use CMake to create your projects, keep reading.

Step 01.00 Create an OGRE application using Xcode-3.2.x and the OGRE Tutorial Framework.

Step 01.01: Create a project folder.

Extract the contents of the TutorialFramework.rar file to a new project folder, e.g. OGRETutorialFramework.

Step 01.02: Create a CMakeLists.txt file with the following contents:

CMakeLists.txt

Copy to clipboard

#/* 
#-----------------------------------------------------------------------------
#Filename:    CMakeLists.txt
#-----------------------------------------------------------------------------
#
#This source file is part of the
#   ___                 __    __ _ _    _ 
#  /___\__ _ _ __ ___  / / /\ \ (_) | _(_)
# //  // _` | '__/ _ \ \ \/  \/ / | |/ / |
#/ \_// (_| | | |  __/  \  /\  /| |   <| |
#\___/ \__, |_|  \___|   \/  \/ |_|_|\_\_|
#      |___/                              
#      Tutorial Framework
#      http://www.ogre3d.org/tikiwiki/
#-----------------------------------------------------------------------------
#*/

cmake_minimum_required(VERSION 2.6)
set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS TRUE)
cmake_policy(SET CMP0003 NEW)

# Use relative paths
# This is mostly to reduce path size for command-line limits on windows
if(WIN32)
  # This seems to break Xcode projects so definitely don't enable on Apple builds
  set(CMAKE_USE_RELATIVE_PATHS true)
  set(CMAKE_SUPPRESS_REGENERATION true)
  set(CMAKE_MODULE_PATH "$ENV{OGRE_HOME}/CMake/;${CMAKE_MODULE_PATH}")
  set(OGRE_SAMPLES_INCLUDEPATH
      $ENV{OGRE_HOME}/Samples/include)
endif()

set(OGRE_PROJECT_NAME
  "OGRETutorialFramework"
)

set(CMAKE_INSTALL_PREFIX "/Users/elvis/Project/DR/Tutorial/OGRE/OGRETutorialFramework/build/bin")

project(${OGRE_PROJECT_NAME})

# Include necessary submodules
set(OGRE_SOURCE_DIR "/Users/elvis/Tool/ogre-1.7.1")
set(CMAKE_MODULE_PATH 
  "${OGRE_SOURCE_DIR}/CMake"
  "${OGRE_SOURCE_DIR}/CMake/Utils" 
  "${OGRE_SOURCE_DIR}/CMake/Packages"
)
set(OGRE_SAMPLES_INCLUDEPATH
  "${OGRE_SOURCE_DIR}/Samples/Common/include"
)
include(CMakeDependentOption)
include(CheckCXXCompilerFlag)
include(MacroLogFeature)
include(OgreConfigTargets)
include(PreprocessorUtils)
set(OGRE_TEMPLATES_DIR "${OGRE_SOURCE_DIR}/CMake/Templates")
 

#####################################################################
# Set up the basic build environment
#####################################################################
 
if (CMAKE_BUILD_TYPE STREQUAL "")
  # CMake defaults to leaving CMAKE_BUILD_TYPE empty. This screws up
  # differentiation between debug and release builds.
  set(CMAKE_BUILD_TYPE "RelWithDebInfo" CACHE STRING "Choose the type of build, options are: None (CMAKE_CXX_FLAGS or CMAKE_C_FLAGS used) Debug Release RelWithDebInfo MinSizeRel." FORCE)
endif ()
 
if (NOT APPLE)
  # Create debug libraries with _d postfix
  set(CMAKE_DEBUG_POSTFIX "_d")
endif ()

# Set compiler specific build flags
if (CMAKE_COMPILER_IS_GNUCXX)
  check_cxx_compiler_flag(-msse OGRE_GCC_HAS_SSE)
  if (OGRE_GCC_HAS_SSE)
    add_definitions(-msse)
  endif ()
endif ()
if (MSVC)
  if (CMAKE_BUILD_TOOL STREQUAL "nmake")
    # set variable to state that we are using nmake makefiles
	set(NMAKE TRUE)
  endif ()
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /fp:fast")
  # Enable intrinsics on MSVC in debug mode
  set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /Oi")
  if (CMAKE_CL_64)
    # Visual Studio bails out on debug builds in 64bit mode unless
	# this flag is set...
	set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /bigobj")
	set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} /bigobj")
  endif ()
endif ()
if (MINGW)
  add_definitions(-D_WIN32_WINNT=0x0500)
endif ()

if (CMAKE_COMPILER_IS_GNUCXX AND NOT MINGW)
  # Test for GCC visibility
  include(CheckCXXCompilerFlag)
  check_cxx_compiler_flag(-fvisibility=hidden OGRE_GCC_VISIBILITY)
  if (OGRE_GCC_VISIBILITY)
    # determine gcc version
    execute_process(COMMAND ${CMAKE_CXX_COMPILER} -dumpversion 
      OUTPUT_VARIABLE OGRE_GCC_VERSION)
    message(STATUS "Detected g++ ${OGRE_GCC_VERSION}")
    message(STATUS "Enabling GCC visibility flags")
    set(OGRE_GCC_VISIBILITY_FLAGS "-DOGRE_GCC_VISIBILITY -fvisibility=hidden")
  
    # check if we can safely add -fvisibility-inlines-hidden
    string(TOLOWER "${CMAKE_BUILD_TYPE}" OGRE_BUILD_TYPE)
    if (OGRE_BUILD_TYPE STREQUAL "debug" AND OGRE_GCC_VERSION VERSION_LESS "4.2")
      message(STATUS "Skipping -fvisibility-inlines-hidden due to possible bug in g++ < 4.2")
    else ()
      set(OGRE_GCC_VISIBILITY_FLAGS "${OGRE_GCC_VISIBILITY_FLAGS} -fvisibility-inlines-hidden")
    endif ()
  endif (OGRE_GCC_VISIBILITY)
  
  # Fix x64 issues on Linux
  if("${CMAKE_SYSTEM_PROCESSOR}" STREQUAL "x86_64" AND NOT APPLE)
    add_definitions(-fPIC)
  endif()  
endif (CMAKE_COMPILER_IS_GNUCXX AND NOT MINGW)

# determine system endianess
#include(TestBigEndian)
#test_big_endian(OGRE_TEST_BIG_ENDIAN)
set(OGRE_TEST_BIG_ENDIAN FALSE)

# Add OgreMain include path
include_directories("${OGRE_SOURCE_DIR}/OgreMain/include")
include_directories("${OGRE_BINARY_DIR}/include")
if (APPLE)
  if (OGRE_BUILD_PLATFORM_IPHONE OR OGRE_BUILD_PLATFORM_APPLE_IOS)
    include_directories("${OGRE_SOURCE_DIR}/OgreMain/include/iPhone")

    # Set static early for proper dependency detection
    set(OGRE_STATIC TRUE)
  else ()
    include_directories("${OGRE_SOURCE_DIR}/OgreMain/include/OSX")
  endif ()
endif (APPLE)

 
find_package(OGRE REQUIRED)
 
if(NOT "${OGRE_VERSION_NAME}" STREQUAL "Cthugha")
  message(SEND_ERROR "You need Ogre 1.7 Cthugha to build this.")
endif()
 
find_package(OIS REQUIRED)
 
if(NOT OIS_FOUND)
	message(SEND_ERROR "Failed to find OIS.")
endif()
 
# Find Boost
if (NOT OGRE_BUILD_PLATFORM_IPHONE AND NOT OGRE_BUILD_PLATFORM_APPLE_IOS)
	if (WIN32 OR APPLE)
		set(Boost_USE_STATIC_LIBS TRUE)
	else ()
		# Statically linking boost to a dynamic Ogre build doesn't work on Linux 64bit
		set(Boost_USE_STATIC_LIBS ${OGRE_STATIC})
	endif ()
	if (MINGW)
		# this is probably a bug in CMake: the boost find module tries to look for
		# boost libraries with name libboost_*, but CMake already prefixes library
		# search names with "lib". This is the workaround.
		set(CMAKE_FIND_LIBRARY_PREFIXES ${CMAKE_FIND_LIBRARY_PREFIXES} "")
	endif ()
	set(Boost_ADDITIONAL_VERSIONS "1.42" "1.42.0" "1.41.0" "1.41" "1.40.0" "1.40" "1.39.0" "1.39" "1.38.0" "1.38" "1.37.0" "1.37" )
	# Components that need linking (NB does not include header-only components like bind)
	set(OGRE_BOOST_COMPONENTS thread date_time)
	find_package(Boost COMPONENTS ${OGRE_BOOST_COMPONENTS} QUIET)
	if (NOT Boost_FOUND)
		# Try again with the other type of libs
		set(Boost_USE_STATIC_LIBS NOT ${Boost_USE_STATIC_LIBS})
		find_package(Boost COMPONENTS ${OGRE_BOOST_COMPONENTS} QUIET)
	endif()
	find_package(Boost QUIET)
 
	# Set up referencing of Boost
	include_directories(${Boost_INCLUDE_DIR})
	add_definitions(-DBOOST_ALL_NO_LIB)
	set(OGRE_LIBRARIES ${OGRE_LIBRARIES} ${Boost_LIBRARIES})
endif()
 
set(HDRS
	./BaseApplication.h
	./TutorialApplication.h
)
 
set(SRCS
	./BaseApplication.cpp
	./TutorialApplication.cpp
)
 
include_directories( ${OIS_INCLUDE_DIRS}
	${OGRE_INCLUDE_DIRS}
	${OGRE_SAMPLES_INCLUDEPATH}
)
 
add_executable(${OGRE_PROJECT_NAME} WIN32 ${HDRS} ${SRCS})
 
set_target_properties(${OGRE_PROJECT_NAME} PROPERTIES DEBUG_POSTFIX _d)
 
target_link_libraries(${OGRE_PROJECT_NAME} ${OGRE_LIBRARIES} ${OIS_LIBRARIES})
 
file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/dist/bin)
file(MAKE_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/dist/media)
 
# post-build copy for win32
if(WIN32 AND NOT MINGW)
	add_custom_command( TARGET ${OGRE_PROJECT_NAME} PRE_BUILD
		COMMAND if not exist .\\dist\\bin mkdir .\\dist\\bin )
	add_custom_command( TARGET ${OGRE_PROJECT_NAME} POST_BUILD
		COMMAND copy \"$(TargetPath)\" .\\dist\\bin )
endif(WIN32 AND NOT MINGW)
if(MINGW)
	set(EXECUTABLE_OUTPUT_PATH ${PROJECT_BINARY_DIR}/dist/bin)
endif(MINGW)
 
if(WIN32)
 
	install(TARGETS ${OGRE_PROJECT_NAME}
		RUNTIME DESTINATION bin
		CONFIGURATIONS All)
 
	install(DIRECTORY ${CMAKE_SOURCE_DIR}/dist/Media
		DESTINATION ./
		CONFIGURATIONS Release RelWithDebInfo Debug
	)
 
	install(FILES ${CMAKE_SOURCE_DIR}/dist/bin/plugins.cfg
		${CMAKE_SOURCE_DIR}/dist/bin/resources.cfg
		DESTINATION bin
		CONFIGURATIONS Release RelWithDebInfo
	)
 
	install(FILES ${CMAKE_SOURCE_DIR}/dist/bin/plugins_d.cfg
		${CMAKE_SOURCE_DIR}/dist/bin/resources_d.cfg
		DESTINATION bin
		CONFIGURATIONS Debug
	)
 
	install(FILES ${OGRE_PLUGIN_DIR_REL}/OgreMain.dll
		${OGRE_PLUGIN_DIR_REL}/RenderSystem_Direct3D9.dll
		${OGRE_PLUGIN_DIR_REL}/RenderSystem_GL.dll
		${OGRE_PLUGIN_DIR_REL}/OIS.dll
		DESTINATION bin
		CONFIGURATIONS Release RelWithDebInfo
	)
 
	install(FILES ${OGRE_PLUGIN_DIR_DBG}/OgreMain_d.dll
		${OGRE_PLUGIN_DIR_DBG}/RenderSystem_Direct3D9_d.dll
		${OGRE_PLUGIN_DIR_DBG}/RenderSystem_GL_d.dll
		${OGRE_PLUGIN_DIR_DBG}/OIS_d.dll
		DESTINATION bin
		CONFIGURATIONS Debug
	)
endif(WIN32)

Step 01.03: Modify the template CMakeLists.txt as follows:

Specify the OGRE project name

Copy to clipboard

set(OGRE_PROJECT_NAME
  "OGRETutorialFramework"
)

Specify the OGRE source installation

Copy to clipboard

set(OGRE_SOURCE_DIR "/Users/elvis/Tool/ogre-1.7.1")

Step 01.04: Use CMake to create the Xcode project.

Run CMake using the command line configuration utility. You may need to set the OGRE_HOME environment variable first if you get the Could not locate OGRE error

Copy to clipboard

$ export OGRE_HOME=/Users/elvis/Tool/ogre-1.7.1
$ cd OGRETutorialFramework
$ mkdir build
$ cd build
$ ccmake -GXcode ..

Update the CMake settings

Copy to clipboard

CMAKE_INSTALL_PREFIX = ${HOME}/Project/OGRE/OGRETutorialFramework/build/install

Press c to configure, and then press q to quit.

Step 01.05: Use Xcode to build the OGRE project.

Launch XCode using the newly generated OGRETutorialFramework.xcodeproj file.
Edit the project settings, by clicking on menu option Project > Project Settings and modifying the following entries:

Copy to clipboard

Architectures = i386 x86_64
Base SDK = Current Mac OS
C/C++ Compiler Version = LLVM-GCC 4.2
Instruction Scheduling = None

Click on menu option Build > Build to build the project.
This will build the OGRETutorialFramework application executable in the OGRETutorialFramework/build/RelWithDebInfo folder.

Step 01.06: Copy the OGRE resource and plugin configuration files to the application folder.

Copy the resouces.cfg and plugins.cfg files to the your OGRE application folder, which in this case, would be OGRETutorialFramework/build/RelWithDebInfo

resources.cfg

Copy to clipboard

# Resources required by the sample browser and most samples.
[Essential]
Zip=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/packs/SdkTrays.zip
FileSystem=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/thumbnails

# Common sample resources needed by many of the samples.
# Rarely used resources should be separately loaded by the
# samples which require them.
[Popular]
FileSystem=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/fonts
FileSystem=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/materials/programs
FileSystem=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/materials/scripts
FileSystem=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/materials/textures
FileSystem=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/materials/textures/nvidia
FileSystem=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/models
FileSystem=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/particle
FileSystem=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/DeferredShadingMedia
FileSystem=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/PCZAppMedia
FileSystem=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/RTShaderLib
FileSystem=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/RTShaderLib/materials
Zip=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/packs/cubemap.zip
Zip=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/packs/cubemapsJS.zip
Zip=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/packs/dragon.zip
Zip=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/packs/fresneldemo.zip
Zip=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/packs/ogretestmap.zip
Zip=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/packs/ogredance.zip
Zip=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/packs/Sinbad.zip
Zip=/Users/elvis/Tool/ogre-1.7.1/Samples/Media/packs/skybox.zip

[General]
FileSystem=/Users/elvis/Tool/ogre-1.7.1/Samples/Media

plugins.cfg

Copy to clipboard

# Defines plugins to load

# Define plugin folder
PluginFolder=/usr/local/lib/

# Define plugins
# Plugin=RenderSystem_Direct3D9
# Plugin=RenderSystem_Direct3D10
# Plugin=RenderSystem_Direct3D11
 Plugin=RenderSystem_GL
# Plugin=RenderSystem_GLES
 Plugin=Plugin_ParticleFX
 Plugin=Plugin_BSPSceneManager
 Plugin=Plugin_CgProgramManager
 Plugin=Plugin_PCZSceneManager
 Plugin=Plugin_OctreeZone
 Plugin=Plugin_OctreeSceneManager

Ensure that you update the location of the plugins in the plugin.cfg file.

Step 01.07: Run the OGRE application.

Type the following commands into a terminal to run the application

Copy to clipboard

cd OGRETutorialFramework/build/RelWithDebInfo
$ ./OGRETutorialFramework

Step 02.00: Resolve issues that you may encounter when attempting to run the OGRE application.

Issue 01: Duplicate libjpeg.dylib in you $DYLD_LIBRARY_PATH.

If you get issues relating to duplicate libjpeg.dylib installed in /usr/local/lib, then make sure that you remove any references to that path in the $DYLD_LIBRARY_PATH environment variable, defined in your .profile.

This is probably because OGRE links to libJPEG.dylib, plus case-preserving but case-insensitive makes it see them as the same library (when DYLD env vars are messed with).

Copy to clipboard

$ otool -L /System/Library/Frameworks/ApplicationServices.framework/Frameworks/ImageIO.framework/ImageIO 
... 
/System/Library/Frameworks/ApplicationServices.framework/Versions/A/Frameworks/ImageIO.framework/Versions/A/Resources/libJPEG.dylib (compatibility version 1.0.0, current version 1.0.0) 
...

Instead define the $DYLD_FALLBACK_LIBRARY_PATH environment variable

Copy to clipboard

export DYLD_FALLBACK_LIBRARY_PATH = $HOME/lib;/usr/local/lib;/usr/lib

Issue 02: OGRE EXCEPTION(6:FileNotFoundException): 'resources.cfg' file not found!

Ensure that the resouces.cfg file generated from the ORGRE build process, located in build/bin is put in the same location as your application executable.

Issue 03: OpenGL rendering subsystem and OGRE plugins not getting loaded.

Ensure that the plugins.cfg file is located in the same folder as your application executable. Also ensure that you specify the location of the OGRE plugins, in the pluging.cfg file as follows:

Issue 04: Window doesn't seem to get focus.

If the application window is unable to get focus, the parameters in the configuration dialog cannot be changed, and the application will not receive mouse and keyboard input events. Add the following line to the CMakeList.txt file to create a bundle for the application:

Copy to clipboard

set_property(TARGET ${OGRE_PROJECT_NAME} PROPERTY MACOSX_BUNDLE TRUE)

History

Enable pagination rows per page

Information	Version
Sun 11 of Sep, 2011 19:23 GMT-0000 barkbeetle89 Added a link to the "Manually configure an Xcode 4 project" page	29
Thu 08 of Sep, 2011 00:12 GMT-0000 jacmoe	28
Wed 07 of Sep, 2011 19:16 GMT-0000 marcwren	27
Wed 07 of Sep, 2011 01:15 GMT-0000 masterfalcon typo	26
Sat 06 of Aug, 2011 05:51 GMT-0000 masterfalcon	25
Sat 06 of Aug, 2011 05:49 GMT-0000 masterfalcon Removed compiler forcing as it's no longer needed and added checks for Byatis iOS definition	24
Mon 01 of Aug, 2011 00:19 GMT-0000 jacmoe	23
Tue 01 of Mar, 2011 02:19 GMT-0000 svenito	22
Tue 01 of Mar, 2011 02:18 GMT-0000 svenito Gets around the Could not locate OGRE error when creating xocde project	21
Thu 21 of Oct, 2010 14:38 GMT-0000 jacmoe	20
Thu 21 of Oct, 2010 14:37 GMT-0000 jacmoe	19
Thu 21 of Oct, 2010 14:36 GMT-0000 jacmoe	18
Wed 22 of Sep, 2010 16:22 GMT-0000 elvisjohndowson	17
Wed 22 of Sep, 2010 16:21 GMT-0000 elvisjohndowson	16
Wed 22 of Sep, 2010 16:20 GMT-0000 elvisjohndowson	15
Wed 22 of Sep, 2010 16:18 GMT-0000 elvisjohndowson	14
Wed 22 of Sep, 2010 16:16 GMT-0000 elvisjohndowson	13
Wed 22 of Sep, 2010 16:13 GMT-0000 elvisjohndowson	12
Wed 22 of Sep, 2010 16:12 GMT-0000 elvisjohndowson	11
Wed 22 of Sep, 2010 16:11 GMT-0000 elvisjohndowson	10
Wed 22 of Sep, 2010 16:06 GMT-0000 elvisjohndowson	9
Wed 22 of Sep, 2010 16:04 GMT-0000 elvisjohndowson	8
Wed 22 of Sep, 2010 16:00 GMT-0000 elvisjohndowson	7
Wed 22 of Sep, 2010 15:44 GMT-0000 elvisjohndowson	6
Wed 22 of Sep, 2010 15:36 GMT-0000 elvisjohndowson	5

«
1 (current)
2
»

Navigation and related functionality and content

History: Setting Up An Application - Mac OSX

Preview of version: 27

Introduction

Step 01.00 Create an OGRE application using Xcode-3.2.x and the OGRE Tutorial Framework.

Step 01.01: Create a project folder.

Step 01.02: Create a CMakeLists.txt file with the following contents:

Step 01.03: Modify the template CMakeLists.txt as follows:

Step 01.04: Use CMake to create the Xcode project.

Step 01.05: Use Xcode to build the OGRE project.

Step 01.06: Copy the OGRE resource and plugin configuration files to the application folder.

Step 01.07: Run the OGRE application.

Step 02.00: Resolve issues that you may encounter when attempting to run the OGRE application.

Issue 01: Duplicate libjpeg.dylib in you $DYLD_LIBRARY_PATH.

Issue 02: OGRE EXCEPTION(6:FileNotFoundException): 'resources.cfg' file not found!

Issue 03: OpenGL rendering subsystem and OGRE plugins not getting loaded.

Issue 04: Window doesn't seem to get focus.

History