History: Accurate per-pixel sphere mapping with normal map influence

Source of version: 4 (current)

{maketoc}



!General
Single pass, 2 lights, per pixel, lambert diffuse, phong specular (with specular mapping) and reflective sphere map CG shader. All channels influenced by the normal map, even the ambient!
Mesh is required to have embedded NORMAL, TANGENT and BINORMAL info. 

In general this should be an expensive shader since everything is done in the fragment, BUT this also gives the best results.

!!Variables
*uvScale: To tile the texture.
*ambient: Brighten up the diffuse.
*diffuseColor: Base color of the object.
*reflectivity: Linear interpolation between the diffuse and the spheremap.
*specularPower0: Phong coefficient of light 0.
*specularPower1: Phong coefficient of light 1.
*specularMultiplier0: FInal multiplier of specular for light 0. To manipulate specular intensity.
*specularMultiplier1: FInal multiplier of specular for light 1.
*useSpecular: Enable/Disable specular highlights.

!!Images
Lambert diffuse perturbed by normal.
{IMG(src="http://toglia3d.com/ogre/LambertPhongSphere_4.jpg")}{IMG}


Low phong specular, no reflection.
{IMG(src="http://toglia3d.com/ogre/LambertPhongSphere_0.jpg")}{IMG}


Reflection = 0.2.
{IMG(src="http://toglia3d.com/ogre/LambertPhongSphere_1.jpg")}{IMG}


High phong specular. Note that ambient is also perturbed by the normal map.
{IMG(src="http://toglia3d.com/ogre/LambertPhongSphere_2.jpg")}{IMG}


Reflection = 1.
{IMG(src="http://toglia3d.com/ogre/LambertPhongSphere_3.jpg")}{IMG}

!!CG shader

{CODE(wrap="1", colors="c++")}//   Title: 
//   Single Pass, 2 Lights, per-pixel CG shader with Lambert diffuse, Phong specular, and Spheremap reflection.
//   Every channel is normal perturbed.
//   Precision over performance.
//   Requires meshes to have embedded TANGENT and BINORMAL info.

//   Author: Alberto Toglia (ogre user:toglia)

//   License: AS IS; Use it for whatever reason (commercial, open source...), modify it as you like. Don't bother letting me know. ;)

float3 expand(float3 v)
{
   return (v - 0.5) * 2;
}

void main_vs(
   float4 position:                    POSITION,
   float2 uv:                          TEXCOORD0,
   float4 normal:                      NORMAL,   
   float4 binormal:                    BINORMAL,
   float4 tangent:                     TANGENT,      
   
   out float4 oPosition_W:             POSITION,
   out float2 oUV:                     TEXCOORD0,
   out float4 oPosition_OS:            TEXCOORD1,      
   out float4 oNormal_OS:              TEXCOORD2,
   out float4 oBinormal_OS:            TEXCOORD3,
   out float4 oTangent_OS:             TEXCOORD4,
   
   uniform float4x4 worldViewProjMatrix
){
   oPosition_W = mul(worldViewProjMatrix, position);
   oUV = uv;
   oPosition_OS = position;
   oNormal_OS = normal;
   oBinormal_OS = binormal;
   oTangent_OS = tangent;
}

float4 main_ps(
   float2 uv:                         TEXCOORD0,      
   float4 position_OS:                TEXCOORD1,      
   float4 normal_OS:                  TEXCOORD2,
   float4 binormal_OS:                TEXCOORD3,
   float4 tangent_OS:                 TEXCOORD4,   
      
   uniform float2 uvScale,
   uniform float4 ambient,
   uniform float4 diffuseColor,
   uniform float reflectivity,   
   uniform float specularPower0,
   uniform float specularPower1,
   uniform float specularMultiplier0,
   uniform float specularMultiplier1,   
   uniform float useSpecular,
   
   uniform float4x4 inverseViewMatrix,
   
   uniform float3 cameraPosition_OS,
   
   uniform float4 lightPosition0_OS,
   uniform float4 lightPosition1_OS,
   
   uniform float4 lightDiffuse0,
   uniform float4 lightDiffuse1,
   
   uniform float4 lightSpecular0,
   uniform float4 lightSpecular1,   
   
   uniform sampler2D NormalMap:            TEXUNIT0,
   uniform sampler2D SpecularMap:          TEXUNIT1,
   uniform sampler2D SphereMap:            TEXUNIT2
) : COLOR {
   
   //Expanding the texture to make it signed; generally comes unsigned
   float3 normalTexture = expand(tex2D(NormalMap, uv*uvScale).xyz);
      
   //Normal, Binormal and Tangent in Object Space
   //Normalization made in the fragment shader to get nicer results; although its more expensive here (Perpixel)
   float3 N_OS = normalize(normal_OS.xyz);
   float3 B_OS = normalize(binormal_OS.xyz);
   float3 T_OS = normalize(tangent_OS.xyz);
   
   //Normal, Binormal and Tangent in ViewSpace
   float3 N_VS = mul(normal_OS.xyz,(float3x3)inverseViewMatrix);
   float3 B_VS = mul(binormal_OS.xyz,(float3x3)inverseViewMatrix);
   float3 T_VS = mul(tangent_OS.xyz,(float3x3)inverseViewMatrix);   
   
   //Making the rotation matrices
   float3x3 rotation_2_TS = float3x3(T_OS, B_OS, N_OS);
   float3x3 rotation_2_VS = float3x3(T_VS, B_VS, N_VS);
   
   //Putting the final normal vector (object normal + texture normal) in tangent space.
   //This vector is used to influence the phong specular highlight with the normal texture.
   //Note that the normal texture came in tangent space, for that reason we need to convert -
   //the object normal (N_OS) in tangent space too.
   float3 normal_TS = normalize(normalize(mul(rotation_2_TS,N_OS))+normalize(normalTexture));
   
   //Putting the final normal vector in view space.
   //This vector is used to influence the reflective sphere mapping with the normal texture.
   float3 normal_VS = normalize(mul(normalTexture,rotation_2_VS));
   
   float3 cameraDirection_OS = normalize(cameraPosition_OS - position_OS.xyz);
   float3 cameraDirection_TS = normalize(mul(rotation_2_TS,cameraDirection_OS));   
      
   float3 lightDirection0_OS = normalize(lightPosition0_OS.xyz - (position_OS.xyz * lightPosition0_OS.w));
   float3 lightDirection1_OS = normalize(lightPosition1_OS.xyz - (position_OS.xyz * lightPosition1_OS.w));   
   float3 lightDirection0_TS = mul(rotation_2_TS,lightDirection0_OS);
   float3 lightDirection1_TS = mul(rotation_2_TS,lightDirection1_OS);
   
   //Simple lambert diffuse
   float light0 = saturate(dot(N_OS,lightDirection0_OS));
   float light1 = saturate(dot(N_OS,lightDirection1_OS));

   //Normal channel for the lambert diffuse.
   float normal0 = saturate(dot(normalTexture, lightDirection0_TS));
   float normal1 = saturate(dot(normalTexture, lightDirection1_TS));      
   
   //Tint diffuse with light information.
   float4 diffuse0 = light0*lightDiffuse0*normal0;   
   float4 diffuse1 = light1*lightDiffuse1*normal1;
   
   //Sphere map sampling with normals in viewspace
   float4 reflectedColor = tex2D(SphereMap, float2(0.5,-0.5) * normal_VS.xy + float2(0.5, 0.5));
   
   //Linear interpolation between the final diffuse and the reflection sphere map
   float4 diffuse = lerp(diffuse0+diffuse1,reflectedColor,reflectivity);
   
   //This is CRAZY!!! Not very mathematical, but it looks good.
   //Why you want this? When pushing ambient values, although the shadows are brigther no normal perturbation is visible. Simulate it!
   //Calculate the normal as if the light source was the camera.
   float ambientNormal = saturate(dot(normalTexture,cameraDirection_TS));   
   
   if(useSpecular>0){   
      //Sample the specular map
      float4 specularTexture = tex2D(SpecularMap, uv*uvScale);
   
      //Normal_TS is already influenced by the normal texture so we have to do everything in Tangent Space
      float3 lightReflection0_TS = reflect(-lightDirection0_TS,normal_TS);
      float3 lightReflection1_TS = reflect(-lightDirection1_TS,normal_TS);
   
      //Phong specular model. (Note: this is different than the Blinn lighting model.
      //Phong is more expensive but give smoother results.
      float RdotV0 = saturate(dot(lightReflection0_TS,cameraDirection_TS));
      float RdotV1 = saturate(dot(lightReflection1_TS,cameraDirection_TS));
      
      //Tint the specular with the light specular color.
      float4 specular0 = pow(RdotV0,specularPower0)*lightSpecular0*specularMultiplier0;
      float4 specular1 = pow(RdotV1,specularPower1)*lightSpecular1*specularMultiplier1;
      
      return (ambient*ambientNormal)+diffuse*diffuseColor+(specular0+specular1)*specularTexture;      
   }else{
      return (ambient*ambientNormal)+diffuse*diffuseColor;
   }   
}{CODE}



!!Ogre Material
{CODE(wrap="1", colors="c++")}vertex_program ppPhongNormalSphereMap_vp cg
{
   source ppPhongNormalSphereMap.cg
   entry_point main_vs
   profiles vs_1_1 arbvp1
}

fragment_program ppPhongNormalSphereMap_fp cg
{
   source ppPhongNormalSphereMap.cg
   entry_point main_ps
   profiles ps_2_0 arbfp1
}

material ppPhongNormalSphereMap
{
   technique
   {       
      pass
      {
         vertex_program_ref ppPhongNormalSphereMap_vp
         {            
            param_named_auto   worldViewProjMatrix         worldviewproj_matrix
         }

         fragment_program_ref ppPhongNormalSphereMap_fp
         {   
            param_named_auto   inverseViewMatrix         inverse_view_matrix
            
            param_named_auto   cameraPosition_OS         camera_position_object_space
            
            param_named_auto   lightPosition0_OS         light_position_object_space 0
            param_named_auto   lightPosition1_OS         light_position_object_space 1
            
            param_named_auto   lightDiffuse0            light_diffuse_colour 0
            param_named_auto   lightDiffuse1            light_diffuse_colour 1
            
            param_named_auto   lightSpecular0            light_specular_colour 0
            param_named_auto   lightSpecular1            light_specular_colour 1
            
            param_named uvScale float2 1 1
            param_named ambient float4 0.0 0.0 0.0 1.0
            param_named diffuseColor float4 0.0 0.0 0.0 1.0
            
            //Linear interpolation between the diffuse and the spheremap
            param_named reflectivity float 1
            
            //Phong exponent
            param_named specularPower0 float 5
            param_named specularPower1 float 5
            
            //In some cases its necesarry to lower the brightness of the speculararity (different than the power)
            param_named specularMultiplier0 float 0.75
            param_named specularMultiplier1 float 0.75
            
            //Turn on or off the phong specular higlight; Higher than 0 is considered ON
            param_named useSpecular float 0
         }         
         
         texture_unit
         {
            texture_alias NormalMap
         }
         
         texture_unit
         {
            texture_alias SpecularMap
         }
         
         texture_unit
         {
            texture_alias ReflectionMap
         }
      }
   }
}


material pelotaMaterial : ppPhongNormalSphereMap
{   
   set_texture_alias NormalMap      leather_normal.png
   set_texture_alias SpecularMap    leather_specular.png
   set_texture_alias ReflectionMap  spheremapWinter.png
}{CODE}

!!Textures
The original leather texture is not mine, it was taken from [http://search.4shared.com/search.html?searchmode=2&searchName=Furnishings.Fabrics.Leather.Bump|here]. I'm not sure what license it has.
{img fileId="2053" thumb="y" rel="box[g]"}
{img fileId="2054" thumb="y" rel="box[g]"}
The sphere map from [http://www.oakcorp.net/chaos/hdri.shtml|here]
{img fileId="2055" thumb="y" rel="box[g]"}

---
Alias: (alias(PerPixel Lambert Diffuse, Phong Specular, Reflective Spheremap. Using specular and normal map influence))
History: Accurate per-pixel sphere mapping with normal map influence

Source of version: 4 (current)

Search by Tags

Latest Changes

Search

Online Users
