Introduction

This article will explain how to embed an OGRE view inside a standard Cocoa window on Mac OS X. This will allow you to use standard Cocoa controls to work with your application.

For simplicity, I am containing almost all the code in a single file. However, in an actual program, you would probably refactor some of this to the appropriate classes.

I assume that you have successfully downloaded or built the OGRE SDK and were able to run the samples. This code was only tested on OGRE 1.7. This description is for XCode 3 running on Snow Leopard, but should be similar or other versions of XCode or Mac OS X.

I also assume you have a basic understanding of Cocoa, Objective-C/Objective-C++, XCode, and Interface Builder

Some code is modified from the included Sample Browser app, and some is from http://will.thimbleby.net/ogre/tutorial1.html will.thimbleby.net

Steps

1. Open XCode.
2. Create a new Cocoa Application, with a name of your choice. I will be using "Sample" as the name of my application.
3. XCode will have created an application delegate class for you, in my case named SampleAppDelegate.
4. Change the filename of the application delegate from '.m' to '.mm'
   OGRE is a C++ library. Since we will be mixing C++ code to work with OGRE in with the Objective-C of cocoa, we need to use Objective-C++. By changing the filename to '.mm' you make sure it is Objective-C++.
5. Right-click on the "Linked Frameworks" group, and choose "Add Existing Frameworks." Navigate to where you installed Ogre.framework and add it.
6. Right-click on the "Other Sources" group, and choose "Add Existing Frameworks." Navigate to where you installed Ogre.framework, and add all header files from the "Headers" directory
   For some reason XCode had trouble finding the headers unless I did this.
7. Create a new group and name it "Plugins"
8. Right-click on "Plugins" and choose "Add Existing Files." Navigate to where your Ogre libraries are installed, and add "RenderSystem_GL.dylib"
9. Right-click on "Resources" and choose "Add Existing Files." Navigate to the Ogre Samples directory, and from the "Media" directory add "ogrehead.mesh" "Ogre.material" "tusk.jpg" "GreenSkin.jpg" and "spheremap.png"
10. Open the "Targets" group and right click on your app name. Select "Add New Build Phase/Copy FIles Build Phase"
11. Choose "Frameworks" as the copy destination
12. Repeat steps 10 and 11, but choose "Plugins" as the copy destination
13. Drag Ogre.framework to the "Copy Frameworks" build step you just created
14. Drag RenderSystem_GL.dylib to the "Copy Plugins" build step you just created
15. Open the "Resources" group and double-click "MainMenu.xib" to open Interface Builder.
16. In Interface Builder, drag a Custom View to the window, and resize it to your liking.
17. Click on your Custom View, and click the right-most tab "Identity"
18. Change Class to OgreView
19. Save the nib and go back to XCode.
20. Change the content of SampleAppDelegate.h to:
    
    Copy to clipboard

    #import <Cocoa/Cocoa.h>
    #import <Ogre/Ogre.h>
    #import <Ogre/OgreOSXCocoaView.h>
    
    @interface SampleAppDelegate : NSObject <NSApplicationDelegate> {
            NSWindow *window;
    	Ogre::SceneNode *objectNode;
    	OgreView *ogreView;
    }
    
    @property (assign) IBOutlet NSWindow *window;
    @property (assign) IBOutlet OgreView *ogreView;
    
    @end

21. Change the content of SampleAppDelegate.mm to (explanations in comments):
    
    Copy to clipboard

    //
    //  GameV3AppDelegate.m
    //  GameV3
    //
    //  Created by Nathaniel Martin on 1/6/10.
    //  Copyright 2010 __MyCompanyName__. All rights reserved.
    //
    
    #import "SampleAppDelegate.h"
    #include "macUtils.h"
    
    @implementation SampleAppDelegate
    
    @synthesize window, ogreView;
    
    - (void)applicationDidFinishLaunching:(NSNotification *)aNotification {
    	
    		// get platform-specific working directory
    		Ogre::String workDir = Ogre::StringUtil::BLANK;
    		Ogre::String pluginsPath = Ogre::StringUtil::BLANK;
    		workDir = Ogre::macBundlePath() + "/Contents/Resources/";
    		pluginsPath = workDir;
    
    		// get the ogre root
    		Ogre::Root *mRoot = OGRE_NEW Ogre::Root(pluginsPath + "plugins.cfg", workDir + "ogre.cfg", workDir + "ogre.log");
    
    		// set up the render system. Since this is running on Mac, our only option is OpenGL.
    		mRoot->setRenderSystem(mRoot->getRenderSystemByName("OpenGL Rendering Subsystem"));
    	
    		// Initialise without an automatically created window
    		mRoot->initialise(false);
    	
    		// Ask for a new renderwindow passing in the ogreView in our nib file
    		Ogre::NameValuePairList misc;
    		// Pass the handle to the ogreView in our nib
    		misc["externalWindowHandle"] = Ogre::StringConverter::toString((size_t)ogreView);
    		// Tell OGRE that we're using cocoa, so it doesn't need to make a window for us
    		misc["macAPI"] = "cocoa";
    		// Actually create the render window
    		NSRect frame = [ogreView frame];
    		mRoot->createRenderWindow("ogre window", frame.size.width, frame.size.height, false, &misc);
    		// And then get a pointer to it.
    		Ogre::RenderWindow *mWindow = [ogreView ogreWindow];
    		
    		// Create the scene manager
    		Ogre::SceneManager *mSceneMgr = mRoot->createSceneManager(Ogre::ST_GENERIC, "my scene manager");
    
    		// Setup the resource locations, and load resources
    		Ogre::ResourceGroupManager::getSingleton().addResourceLocation(workDir, std::string("FileSystem"), Ogre::ResourceGroupManager::DEFAULT_RESOURCE_GROUP_NAME, false);
    		Ogre::ResourceGroupManager::getSingleton().initialiseAllResourceGroups();
    	
    	
    		// Create the camera, node & attach camera
    		Ogre::Camera *mCamera = mSceneMgr->createCamera("PlayerCam");
    		Ogre::SceneNode* camNode = mSceneMgr->getRootSceneNode()->createChildSceneNode();
    		camNode->attachObject(mCamera);
    		mWindow->addViewport(mCamera);
    	
    		// Create a light
    		mSceneMgr->setAmbientLight(Ogre::ColourValue(0, 0, 0));
    		mSceneMgr->createLight("MainLight");
    	
    		// Add a object, give it it's own node
    		objectNode = mSceneMgr->getRootSceneNode()->createChildSceneNode();
    		Ogre::Entity *head = mSceneMgr->createEntity("head", "ogrehead.mesh");
    
    		objectNode->attachObject(head);
    		objectNode->setPosition(Ogre::Vector3(0, 0, -500));
    	
    		// create a timer that causes OGRE to render at 50fps
    		[NSTimer scheduledTimerWithTimeInterval:0.02 target:self selector:@selector(renderFrame) userInfo:NULL repeats:YES];
    }
    
    - (void)renderFrame
    {
    		// Every time the timer fires, render a frame, and rotate the node
    		Ogre::Root::getSingleton().renderOneFrame();
    		objectNode->rotate(Ogre::Vector3(0, 1, 0), Ogre::Radian(0.01));
    }
    
    @end

22. Right-click on "Resources" and add a new file, "plugins.cfg"
23. Insert one line in "plugins.cfg"
    
    Copy to clipboard

    Plugin=RenderSystem_GL

24. Switch back to Interface Builder and select your Application Delegate
25. Switch to Connections in the inspector, and drag a connection from ogreView to the view you created in the window.
26. Switch back to XCode, build and run, and you should have a rotating ogre head inside your Cocoa window!

Alias: Using_A_Cocoa_Window