Skip to main content
OgreDotNet VB.NET Intermediate Tutorial 5        
2
Page actions
Print

Introduction

NOTE: This tutorial is a conversion of the C# Intermediate Tutorial 5. All the text is exactly the same (apart of the added text of course), only the code is in VB.NET

Well, we've gotten far enough to look at the guts of ExampleApplication and rip out the important parts and build a "hello world" application using OgreDotNet. This is the first of 2 "hello world" applications. In the first part, we'll setup a basic application which still uses the OGRE Config Dialog and Resource scripts. In the second part, we'll get rid of the config dialog and customize our resource script (hopefully).

On second thought... Part 1 isn't really a traditional hello world app, since its sort of bloated, but it's still a good starting point for creating your own application framework (which should be one of your goals)

Getting Started

Open up your VB.NET editor and create a new Console Application. Add a new class file and put in the code that follow in the tutorial.

OK. Let's get started. Since OGRE is a fairly complex API, our starting point is fairly large. We'll need System, System.IO, System.Drawing, Math3D and OgreDotNet.

Copy to clipboard
Imports System
        Imports System.IO
        Imports System.Drawing
        Imports Math3D
        Imports OgreDotNet

There are a few objects which are needed in OGRE no matter what. If you are not familiar with any of them, take a look at the OGRE documentation... I chose to use the same variable names as the example application... Anyway, here they are:

Copy to clipboard
Public mRoot As Root = Nothing
        Public mRenderWindow As RenderWindow = Nothing
        Public mSceneManager As SceneManager = Nothing
        Public mCamera As Camera = Nothing
        Public mViewport As Viewport = Nothing
        Public mEventHandler As OgreDotNet.EventHandler = Nothing
        Public mDone As Boolean = False

I'm not 100% sure mDone is needed, but having a common variable that we can use in our delegates makes things easier. mEventHandler isn't necessary, but without it, we have no way to close the application. (unless you want a really lame ODN application that starts up then closes)

Next, since Root implements IDisposable, we'll do that too since it makes sense.

Copy to clipboard
Class HelloWorldApp
           Implements System.IDisposable

We'll need constructor, a destructor and Dispose methods. Since we don't use any unmanaged memory, we'll call Dispose from the destructor.

Copy to clipboard
Public Sub New()
            MyBase.New()
        End Sub

        Public Sub Dispose() Implements System.IDisposable.Dispose
        End Sub

I mentioned that we're still using the resource scripts so we need a method which does that.

Copy to clipboard
Protected Sub SetupResources(ByVal sFileName As String)
        End Sub

I also decided to use the Start method since it keeps main nice & tidy.

Copy to clipboard
Public Sub Start()
        End Sub

The next three methods are the ones we need for event handling. remember that returning false in either Frame* method kills the app. KeyClicked is here since we want a way to close our app when its running fullscreen.

Copy to clipboard
Protected Function FrameStarted(ByVal e As FrameEvent) As Boolean
        End Function

        Protected Function FrameEnded(ByVal e As FrameEvent) As Boolean
        End Function

        Protected Sub KeyClicked(ByVal e As KeyEvent)
        End Sub

Last, but certainly not least, we need a Sub Main. Open up the module and put in this code:

Copy to clipboard
Module Loader
        Sub Main(ByVal args() As String)
        End Sub
        End Module

Here's what we've got so far:

Hello World Start Code

In your class file, you should have this:

Copy to clipboard
Imports System
 Imports System.IO
 Imports System.Drawing
 Imports Math3D
 Imports OgreDotNet
 
 Namespace OgreDotNetTutorial
 
    Class HelloWorldApp
        Implements System.IDisposable
 
        'Declare & pre-initialize the required elements 
        Public mRoot As Root = Nothing
        Public mRenderWindow As RenderWindow = Nothing
        Public mSceneManager As SceneManager = Nothing
        Public mCamera As Camera = Nothing
        Public mViewport As Viewport = Nothing
        Public mEventHandler As OgreDotNet.EventHandler = Nothing
        Public mDone As Boolean = False
 
        'Constructor
        Public Sub New()
            MyBase.New()
        End Sub
 
        Public Sub Dispose() Implements System.IDisposable.Dispose
        End Sub
 
        Protected Sub SetupResources(ByVal sFileName As String)
        End Sub
 
        Public Sub Start()
        End Sub
 
        Protected Function FrameStarted(ByVal e As FrameEvent) As Boolean
        End Function
 
        Protected Function FrameEnded(ByVal e As FrameEvent) As Boolean
        End Function
 
        Protected Sub KeyClicked(ByVal e As KeyEvent)
        End Sub
 
    End Class
 
 End Namespace

In your module file you should have this:

Copy to clipboard
Module Loader
    Sub Main(ByVal args() As String)
    End Sub
 End Module

Initializing the required objects



We've already declared all the required objects and it makes sense to use the constructor to initialize them.. Find the constructor and lets go to work:

Copy to clipboard
'Create the Root object 
            mRoot = New Root

            'Setup OGRE resources 
            SetupResources("resources.cfg")

            'Show the config Dialog 
            If mRoot.ShowConfigDialog = False Then
                mRoot.Dispose()
                Return
            End If
            'Initialize the RenderWindow 
            mRenderWindow = mRoot.Initialise(True, "[Tutorial 1] Hello World!")

            'Initialize the SceneManager 
            mSceneManager = mRoot.CreateSceneManager(Convert.ToUInt16(SceneType.Generic), "HelloOgreDontNetSceneManager")
            mSceneManager.SetAmbientLight(Color.White)

            'Initialize the Camera 
            mCamera = mSceneManager.CreateCamera("HelloCamera")
            mCamera.SetPosition(0, 0, -200)
            mCamera.LookAt = New Vector3(0, 0, 0)
            mCamera.NearClipDistance = 5

            'Initialize the Viewport 
            mViewport = mRenderWindow.AddViewport(mCamera)
            mViewport.BackgroundColor = Color.Black
            mCamera.AspectRatio = (float)mViewport.ActualWidth / mViewport.ActualHeight

            'Do some "manager" setup. 
            ResourceGroupManager.getSingleton().initialiseAllResourceGroups()
            MaterialManager.Instance.SetDefaultTextureFiltering(TextureFilterOptions.TfoBilinear)
            MaterialManager.Instance.SetDefaultAnisotropy(Convert.ToUInt32(1))
            TextureManager.Instance.SetDefaultNumMipmaps(Convert.ToUInt32(5))

            'Create and Setup the event handler 
            mEventHandler = New OgreDotNet.EventHandler(mRoot, mRenderWindow)
            mEventHandler.SubscribeEvents()
            AddHandler mEventHandler.FrameStarted, AddressOf Me.FrameStarted
            AddHandler mEventHandler.FrameEnded, AddressOf Me.FrameEnded
            AddHandler mEventHandler.KeyClicked, AddressOf Me.KeyClicked

            'Create the Scene 
            Dim ent As Entity
            Dim node As SceneNode

            mSceneManager.SetAmbientLight(Color.White)

            ent = mSceneManager.CreateEntity("Robot", "robot.mesh")
            Node = mSceneManager.GetRootSceneNode().CreateChildSceneNode("RobotNode")
            Node.AttachObject(ent)
            Node.SetPosition(0, 0, 0)

A minimal set of event handlers



There's really only 3 functions which we need here and they are all really basic.
FrameStarted checks if the user wants the window closed

Copy to clipboard
Protected Function FrameStarted(ByVal e As FrameEvent) As Boolean
            If mRenderWindow.Closed = False And mDone = False Then
                Return True
            End If
        End Function

FrameEnded does absolutely nothing..

Copy to clipboard
Protected Function FrameEnded(ByVal e As FrameEvent) As Boolean
            Return True
        End Function

KeyClicked simply looks for the escape key and sets the done variable.

Copy to clipboard
Protected Sub KeyClicked(ByVal e As KeyEvent)
            Select Case e.KeyCode
                Case KeyCode.Escape
                    mDone = True
            End Select
        End Sub

Parsing resources.cfg



I'm not going to go into detail about this. For now, lets just wave our hands at it wait until the part 2 to examine what's actually going on.

Copy to clipboard
Protected Sub SetupResources(ByVal sFileName As String)
            '//Initialiser.SetupResources(sFileName); 
            Dim sr As StreamReader = New StreamReader(sFileName)
            Dim secName As String = "", sLocType, sarchName
            Dim line As String
            Do While sr.Peek() >= 0
                line = sr.ReadLine
                Dim x As Integer = line.IndexOf("#")
                If x > -1 Then
                    line = line.Substring(0, x)
                End If
                line = line.Trim
                If line.Length > 0 Then
                    If line.Chars(0) = "[" Then
                        secName = line.Substring(1, line.Length - 2)
                    ElseIf secName.Length > 0 Then
                        x = line.IndexOf("=")
                        If x <= 0 Then
                            Throw New Exception("Invalid line in resource file " + sFileName)
                        End If
                        sLocType = line.Substring(0, x)
                        sarchName = line.Substring(x + 1)
                        ''Console.WriteLine("-- SetupResources {0}, {1}, {2}", sarchName, sLocType, secName) 
                        ResourceGroupManager.getSingleton.addResourceLocation(sarchName, sLocType, secName)
                    End If
                End If
            Loop
        End Sub

Starting the rendering loop



Calling Root's StartRendering method kicks off the OGRE loop.

Copy to clipboard
Public Sub Start()
            mRoot.StartRendering()
        End Sub

Next, in main, we'll create our app and start it, place this code in your sub main in the module:

Copy to clipboard
Sub Main(ByVal args() As String)
        Dim app As OgreDotNetTutorial.HelloWorldApp
        Try
            app = New OgreDotNetTutorial.HelloWorldApp
            app.Start()
        Catch ex As Exception
            Console.WriteLine("## Exception " & ex.Message & vbCrLf & ex.Source)
        Finally
            Try
                app.Dispose()
            Catch ex As Exception
                Console.WriteLine("## Exception Dispose " & ex.Message & vbCrLf & ex.Source)
            End Try
        End Try
    End Sub

Also put the same Imports on top of it as in your class file.

Disposing of Root

Since Root implements IDisposable, we need to call mRoot.Dispose() in our Dispose method

Copy to clipboard
Public Sub Dispose() Implements System.IDisposable.Dispose
            mEventHandler = Nothing
            mViewport = Nothing
            mCamera = Nothing
            mSceneManager = Nothing
            mRenderWindow = Nothing
            mRoot.Dispose()
        End Sub

The completed code



This is your class file:

Copy to clipboard
Imports System
 Imports System.IO
 Imports System.Drawing
 Imports Math3D
 Imports OgreDotNet
 
 Namespace OgreDotNetTutorial
 
    Class HelloWorldApp
        Implements System.IDisposable
 
        'Declare & pre-initialize the required elements 
        Public mRoot As Root = Nothing
        Public mRenderWindow As RenderWindow = Nothing
        Public mSceneManager As SceneManager = Nothing
        Public mCamera As Camera = Nothing
        Public mViewport As Viewport = Nothing
        Public mEventHandler As OgreDotNet.EventHandler = Nothing
        Public mDone As Boolean = False
 
        'Constructor 
        Public Sub New()
            MyBase.New()
 
            'Create the Root object 
            mRoot = New Root
 
            'Setup OGRE resources 
            SetupResources("resources.cfg")
 
            'Show the config Dialog 
            If mRoot.ShowConfigDialog = False Then
                mRoot.Dispose()
                Return
            End If
            'Initialize the RenderWindow 
            mRenderWindow = mRoot.Initialise(True, "[Tutorial 1] Hello World!")
 
            'Initialize the SceneManager 
            mSceneManager = mRoot.CreateSceneManager(Convert.ToUInt16(SceneType.Generic), "HelloOgreDontNetSceneManager")
            mSceneManager.SetAmbientLight(Color.White)
 
            'Initialize the Camera 
            mCamera = mSceneManager.CreateCamera("HelloCamera")
            mCamera.SetPosition(0, 0, -200)
            mCamera.LookAt = New Vector3(0, 0, 0)
            mCamera.NearClipDistance = 5
 
            'Initialize the Viewport 
            mViewport = mRenderWindow.AddViewport(mCamera)
            mViewport.BackgroundColor = Color.Black
            mCamera.AspectRatio = mViewport.ActualWidth / mViewport.ActualHeight
 
            'Do some "manager" setup. 
            ResourceGroupManager.getSingleton().initialiseAllResourceGroups()
            MaterialManager.Instance.SetDefaultTextureFiltering(TextureFilterOptions.TfoBilinear)
            MaterialManager.Instance.SetDefaultAnisotropy(Convert.ToUInt32(1))
            TextureManager.Instance.SetDefaultNumMipmaps(Convert.ToUInt32(5))
 
            'Create and Setup the event handler 
            mEventHandler = New OgreDotNet.EventHandler(mRoot, mRenderWindow)
            mEventHandler.SubscribeEvents()
            AddHandler mEventHandler.FrameStarted, AddressOf Me.FrameStarted
            AddHandler mEventHandler.FrameEnded, AddressOf Me.FrameEnded
            AddHandler mEventHandler.KeyClicked, AddressOf Me.KeyClicked
 
            'Create the Scene 
            Dim ent As Entity
            Dim node As SceneNode
 
            mSceneManager.SetAmbientLight(Color.White)
 
            ent = mSceneManager.CreateEntity("Robot", "robot.mesh")
            Node = mSceneManager.GetRootSceneNode().CreateChildSceneNode("RobotNode")
            Node.AttachObject(ent)
            Node.SetPosition(0, 0, 0)
 
        End Sub
 
        Public Sub Dispose() Implements System.IDisposable.Dispose
            mEventHandler = Nothing
            mViewport = Nothing
            mCamera = Nothing
            mSceneManager = Nothing
            mRenderWindow = Nothing
            mRoot.Dispose()
        End Sub
 
        Protected Sub SetupResources(ByVal sFileName As String)
            '//Initialiser.SetupResources(sFileName); 
            Dim sr As StreamReader = New StreamReader(sFileName)
            Dim secName As String = "", sLocType, sarchName
            Dim line As String
            Do While sr.Peek() >= 0
                line = sr.ReadLine
                Dim x As Integer = line.IndexOf("#")
                If x > -1 Then
                    line = line.Substring(0, x)
                End If
                line = line.Trim
                If line.Length > 0 Then
                    If line.Chars(0) = "[" Then
                        secName = line.Substring(1, line.Length - 2)
                    ElseIf secName.Length > 0 Then
                        x = line.IndexOf("=")
                        If x <= 0 Then
                            Throw New Exception("Invalid line in resource file " + sFileName)
                        End If
                        sLocType = line.Substring(0, x)
                        sarchName = line.Substring(x + 1)
                        ''Console.WriteLine("-- SetupResources {0}, {1}, {2}", sarchName, sLocType, secName) 
                        ResourceGroupManager.getSingleton.addResourceLocation(sarchName, sLocType, secName)
                    End If
                End If
            Loop
        End Sub
 
        Public Sub Start()
            mRoot.StartRendering()
        End Sub
 
        Protected Function FrameStarted(ByVal e As FrameEvent) As Boolean
            If mRenderWindow.Closed = False And mDone = False Then
                Return True
            End If
        End Function
 
        Protected Function FrameEnded(ByVal e As FrameEvent) As Boolean
            Return True
        End Function
 
        Protected Sub KeyClicked(ByVal e As KeyEvent)
            Select Case e.KeyCode
                Case KeyCode.Escape
                    mDone = True
            End Select
        End Sub
 
    End Class
 End Namespace

This is your module:

Copy to clipboard
Imports System
 Imports System.IO
 Imports System.Drawing
 Imports Math3D
 Imports OgreDotNet
 
 Module Loader
    Sub Main(ByVal args() As String)
        Dim app As OgreDotNetTutorial.HelloWorldApp
        Try
            app = New OgreDotNetTutorial.HelloWorldApp
            app.Start()
        Catch ex As Exception
            Console.WriteLine("## Exception " & ex.Message & vbCrLf & ex.Source)
        Finally
            Try
                app.Dispose()
            Catch ex As Exception
                Console.WriteLine("## Exception Dispose " & ex.Message & vbCrLf & ex.Source)
            End Try
        End Try
    End Sub
 End Module

Credits



Tutorial converted and edited by LennardF

Edited after release by ?

Changes

[+] Fixed the codeblocks — DC

History Source